Shadow Catcher Material

[Tobias_Reidl]

Include the following details (edit as applicable):

• Issue category: Real-time Mapping-Depth / ARDK Documentation / Sample App aka ‘AR Developer Tools
• Device type & OS version: Android / iOS
• Host machine & OS version: Mac Ventura, M1
• Issue Environment : Unity Mock / On Device
• Xcode version:
• ARDK version: 2.3.1.
• Unity version: 2021.3.16

Description of the issue:

Hi y’all. I’m trying to create / find a material / shader, that serves as a shadow caster only, meaning I can attach it to detected planes / meshes or onto a normal Plane game object and it will only cast shadows from other objects.

I found a few tutorials on how to do that in URP:

Realtime AR Shadows – Unity Shader Graph – BrownBot

Unity AR Foundation - How To Apply Shadows To Transparent AR Planes For More Realistic AR?

However none seems to work for me. Would be happy about some advice / material that works with ARDK

cheers and thanks in advance
Tobi

[Merijn_Kersten]

Hey @Tobias_Reidl

Here is a shader that i use in some of my AR projects to cast shadows on planes:
Shader “URP AR Shadow Receiver”
{
Properties
{
_ShadowColor (“Shadow Color”, Color) = (0.35,0.4,0.45,1.0)
}

SubShader
{
    Tags
    {
        "RenderPipeline"="UniversalPipeline"
        "RenderType"="Transparent"
        "Queue"="Transparent-1"
    }

    Pass
    {
        Name "ForwardLit"
        Tags { "LightMode" = "UniversalForward" }

        Blend DstColor Zero, Zero One
        Cull Back
        ZTest LEqual
        ZWrite Off

        HLSLPROGRAM
        #pragma vertex vert
        #pragma fragment frag

        #pragma prefer_hlslcc gles
        #pragma exclude_renderers d3d11_9x
        #pragma target 2.0

        #pragma multi_compile _ _MAIN_LIGHT_SHADOWS
        #pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE
        #pragma multi_compile _ _SHADOWS_SOFT
        #pragma multi_compile_fog

        #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"

        CBUFFER_START(UnityPerMaterial)
        float4 _ShadowColor;
        CBUFFER_END

        struct Attributes
        {
            float4 positionOS : POSITION;
            UNITY_VERTEX_INPUT_INSTANCE_ID
        };

        struct Varyings
        {
            float4 positionCS               : SV_POSITION;
            float3 positionWS               : TEXCOORD0;
            float fogCoord                  : TEXCOORD1;
            UNITY_VERTEX_INPUT_INSTANCE_ID
            UNITY_VERTEX_OUTPUT_STEREO
        };

        Varyings vert (Attributes input)
        {
            Varyings output = (Varyings)0;

            UNITY_SETUP_INSTANCE_ID(input);
            UNITY_TRANSFER_INSTANCE_ID(input, output);
            UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);

            VertexPositionInputs vertexInput = GetVertexPositionInputs(input.positionOS.xyz);
            output.positionCS = vertexInput.positionCS;
            output.positionWS = vertexInput.positionWS;
            output.fogCoord = ComputeFogFactor(vertexInput.positionCS.z);

            return output;
        }

        half4 frag (Varyings input) : SV_Target
        {
            UNITY_SETUP_INSTANCE_ID(input);
            UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);

            half4 color = half4(1,1,1,1);

        #ifdef _MAIN_LIGHT_SHADOWS
            VertexPositionInputs vertexInput = (VertexPositionInputs)0;
            vertexInput.positionWS = input.positionWS;

            float4 shadowCoord = GetShadowCoord(vertexInput);
            half shadowAttenutation = MainLightRealtimeShadow(shadowCoord);
            color = lerp(half4(1,1,1,1), _ShadowColor, (1.0 - shadowAttenutation) * _ShadowColor.a);
            color.rgb = MixFogColor(color.rgb, half3(1,1,1), input.fogCoord);
        #endif
            return color;
        }

        ENDHLSL
    }
}

}

But be aware that for this to work you have to toggle “transparent recieve shadows” on in your renderer asset here:

[Dylan_Smit]

If you want a premade solution, I got a free version on the asset store as well:

Shadow Receiver URP (AR) | VFX Shaders | Unity Asset Store

Shadow Receiver URP (FREE) | VFX Shaders | Unity Asset Store

[Tobias_Reidl]

@Merijn_Kersten @Dylan_Smit , thanks a lot you guys, sadly both solutions do not work for me. The weird thing is that it seems like I do not get shadows on transparent surfaces at all despite activating Transparent Receive shadows…

Take a look at the screenshots, here I tested a normal material, semi transparent and the Shadow Receiver URP Free :

[Dylan_Smit]

Disable shadow cascades. No free version supports it currently. Might help?

[Tobias_Reidl]

Oh yes! Works like a charm, thanks a bunch @Dylan_Smit !